What Second Life has done bad?

• closed ecosystem. Although the client development is open, but the server side is closed. Especially, the world is closed.
• Linden Lab is too ambitious. They want to build all aspects of the next generation of WWW.
• the world is flat. Not that bad, but really not real.
• lame avatar animations and controls

What Second Life has done good?

• one world instance. This is great comparing to WoW.
• the world is being modified continuously by users. This is another important good point comparing to WoW.
• embed 2D pages in 3D world.

What is an ideal implementation?

I really don’t know it clearly, but I think the most important point is to keep the world open. At the server side, any companies/communities/people can create and manage a subset of the world. We can call this role as land service provider, just as nowadays’ page hosting service provider. A sub world may be a small planet, a shopping mall or other weird models.

At the client side, all developers can contribute to Virtual World Traveler, just as nowadays’ browsers. Certainly, there will be many technology standard proposals born and vanish. But surely some will be the winners, just as nowadays’ HTML and CSS.

The HTTP protocol is not good enough for the Virtual World, we need a new protocol, Virtual World Transfer Protocol (VWTP) is a good name, which will keep the connection state alive between the server and clients. The domain system still works, and the coordinate will be important part in URL, such as vwtp://example.com/(x,y). There will be many type of coordinates. The coordinates may have 2, 3 or 4 and more dimensions.

What is the corresponding concepts of HTML/CSS in the Virtual World, maybe they will be the triangle meshes and textures used in nowadays’ 3D games, maybe they are others, hybrid model formats showing in one scene is not a bad idea. Renderer will be a important component in the Virtual World Traveler. Multiple renderers functioning at the same time will be very possible.

AI has not counterpart in nowdays’ browsers.

There will be many creative application types in the Virtual World, such as virtual play fields, virtual theatre, etc.

The Virtual World even will affect the development of future operating systems.

The “Text Typing -> Compile -> Link” model is so successful in the past decades so that other models fall into the shade. But with the coming of mobile age, the situation will change.

Text programming obviously is not a good model in mobile age. How about visual programming? Visual programming really has more natural advantages than text programming. They will surely get a larger market share on mobile devices than PC. But I don’t think traditional visual programmings will be the final winner on mobile devices. If it will, it has defeated text programming on PC already. The reasons why it didn’t win on PC are exact the reasons why it will not will win on mobile device.

(Here, I mean the narrow visual programming definition, for example, LabView. In a wider visual programming definition, using Adobe Flash CS even PhotoShop can also be viewed as visual programming. Artists are programmers, programmers are also artists. :))

What programming language model will win on mobile devices? I really don’t know. But I have a candidate solution, which is a combination of traits from both text programming and traditional visual programming. Finger Programming is a good name for it. But I would call it NoCompiler Programming or YouComiler Programming language. Yes, this type languages need NOT compiler. You, the programmer, is the compiler. When a program is coded done, it is already compiled. We just need a linker to create the final execute program or a no-compiler VM to run it.

It is hard for me to describe clearly how to use NoCompiler languages to program here. If you ever used Phyard Builder’s script editor, you know what I say above. Now the Piapia language, Phyard Builder’s script language, is still far to the perfect implementation of a good NoCompiler language. I will improve it continuously. In fact, the current implementation is much like the script editor of Flash MX Studio (I really don’t know what it is like in Flash CS), but there will be more and more differences.

If NoCompiler programming model, or another model for mobile age, wins text programming, the PC age will be over.
Another impact of NoCompiler languages is the current predicted future Cloud Compilers will become Cloud Linkers.

Flash player 10 introduces FileReference, which makes load local files possible. But for unknown secure reason, you can only display a local image but can’t get the pixels of local images. When you try to cast the Loader.content to a Bitmap instance, a #2148 security error will be thrown. Here is a solution for how to bypass this secure restriction. This solution also works for loading any image file data embedded with ByteArray forms.

Firstly, a template.swf needs to be created for embedding:

package
{
   import flash.display.Sprite;
   import flash.display.Bitmap;

   public class Template extends Sprite
   {
      [Embed(source="small.jpg")]
      public var BitmapClass:Class;

      public function GetBitmap ():Bitmap
      {
         return new BitmapClass ();
      }
   }
}

Note there is a GetBitmap function in it. And you MUST embed a jpg file so that the solution supports 3 image formats: jpg, png and gif. If you are lazy to compile this file, here is one: template.swf

Now you can use the following LocalImageLoader class to replace the core Loader class.

package com.tapirgames.util
{
   import flash.utils.ByteArray;
   import flash.utils.Endian;
   import flash.display.Loader;
   import flash.system.LoaderContext;
   import flash.events.Event;
   import flash.events.ProgressEvent;
   import flash.events.IOErrorEvent;
   import flash.events.SecurityErrorEvent;

   public class LocalImageLoader extends Loader
   {
   // template swf file

      [Embed(source="template.swf", mimeType="application/octet-stream")]
      private static var SwfFile:Class;

   // original data

      private var mOriginalData:ByteArray = null;
      private var mIsBadSwfFile:Boolean; // valid when mOriginalData != null

      private var mStartOffset_TagDefineBitsJPEG2:int;
      private var mEndOffset_TagDefineBitsJPEG2:int;
      private var mCharacterID_TagDefineBitsJPEG2:int;

   // load

      override public function loadBytes (imageFileData:ByteArray, context:LoaderContext = null):void
      {
         try
         {

         // parse

            if (mOriginalData == null)
            {
               var swfFile:ByteArray = new SwfFile ();
               swfFile.endian = Endian.LITTLE_ENDIAN;
               swfFile.position = 8;
               mOriginalData = new ByteArray ();
               mOriginalData.endian = Endian.LITTLE_ENDIAN;
               swfFile.readBytes (mOriginalData);
               mOriginalData.uncompress ();

               var numBits:int = (mOriginalData [0] & 0xFF) >> 3;
               mOriginalData.position = (((numBits << 2) + 5 + 7) >> 3) + 4;

               while (true)
               {
                  var startOffset:int = mOriginalData.position;
                  var tagTypeAndLength:int = mOriginalData.readUnsignedShort ();
                  var tagType:int = tagTypeAndLength >> 6;
                  if (tagType == 0) // end tag
                  {
                     mIsBadSwfFile = true;
                     break;
                  }

                  var tagLength:int = tagTypeAndLength & 0x3f;
                  if (tagLength == 0x3f)
                  {
   	               tagLength = mOriginalData.readInt ();
                  }

                  var endOffset:int = mOriginalData.position + tagLength;

                  if (tagType == 21) // tag DefineBitsJPEG2
                  {
                     mCharacterID_TagDefineBitsJPEG2 = mOriginalData.readShort ();
                     mStartOffset_TagDefineBitsJPEG2 = startOffset;
                     mEndOffset_TagDefineBitsJPEG2 = endOffset;

                     mIsBadSwfFile = false;
                     break;
                  }

                  mOriginalData.position = endOffset;
               }
            }

            mOriginalData.position = 0;

            if (mIsBadSwfFile)
               throw new Error ("bad template swf file");

         // write

            var newData:ByteArray = new ByteArray ();
            newData.endian = Endian.LITTLE_ENDIAN;
            newData.writeBytes (mOriginalData, 0, mStartOffset_TagDefineBitsJPEG2);
            newData.writeShort ((21 << 6) | 0x3f);
            newData.writeInt (2 + imageFileData.length); // 2 for CharacterID
            newData.writeShort (mCharacterID_TagDefineBitsJPEG2);
            if (imageFileData.length > 0)
            {
               newData.writeBytes (imageFileData);
            }
            newData.writeBytes (mOriginalData, mEndOffset_TagDefineBitsJPEG2);
            var newFileLength:int = newData.length + 8;
            newData.compress ();

            var newSwfFile:ByteArray = new ByteArray ();
            newSwfFile.endian = Endian.LITTLE_ENDIAN;
            newSwfFile.writeByte (0x43);
            newSwfFile.writeByte (0x57);
            newSwfFile.writeByte (0x53);
            newSwfFile.writeByte (10);
            newSwfFile.writeUnsignedInt (newFileLength);
            newSwfFile.writeBytes (newData);
            newSwfFile.position = 0;
         }
         catch (error:Error)
         {
            dispatchEvent(new IOErrorEvent(IOErrorEvent.IO_ERROR, false, false, error.message));
         }

      // load, now, no secure errors. Why adobe makes some troubles for developers?

         super.loadBytes (newSwfFile, context);
      }
   }
}

Here is the example on how to use it:

public function LoadLocalImage  (imageFileData:ByteArray):void
{
   //var loader:Loader = new Loader(); // Don't use this
   var loader:LocalImageLoader = new LocalImageLoader ();
   loader.contentLoaderInfo.addEventListener (Event.COMPLETE, OnLoadLocalImageComplete);
   loader.loadBytes (imageFileData);
}

private function OnLoadLocalImageComplete (event:Event):void
{
   // var newBitmap:Bitmap = event.target.content as Bitmap; // Don't use this
   var newBitmap:Bitmap = ((event.target.content.GetBitmap as Function) ()) as Bitmap;
   mBitmap = new Bitmap (newBitmap.bitmapData); // done! no error #2148 will be thrown
}

package
{
   public class Base64
   {
      public static const Base64Chars:String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=";

      private static var Base64Char2Index:Array = null;
      private static function GetBase64Char2IndexTable ():Array
      {
         if (Base64Char2Index == null)
         {
            Base64Char2Index = new Array (128); // all char codes in Base64Chars are smaller than 128

            for (var i_char:int = Base64Chars.length - 2; i_char >= 0; -- i_char) // "Base64Chars.length - 2" is to ignore the "=" cahr
            {
               Base64Char2Index [Base64Chars.charCodeAt (i_char)] = i_char;
            }
         }

         return Base64Char2Index;
      }

      public static function DecodeString2ByteArray (text:String):ByteArray
      {
         if (text == null)
         {
            return null;
         }

         var num_chars:int = text.length;
         var num_triples:int = num_chars / 4;
         var num_extras:int = num_chars - num_triples * 4;

         if (num_extras != 0)
         {
            return null;
         }

         var data:ByteArray = new ByteArray ();

         var b0:int, b1:int, b2:int, b3:int;

         var table_char2index:Array = GetBase64Char2IndexTable ();
         var i_char:int = 0;
         data.position = 0;

         while (i_char < num_chars)
         {
            b0 = table_char2index [text.charCodeAt (i_char ++)];
            b1 = table_char2index [text.charCodeAt (i_char ++)];
            b2 = table_char2index [text.charCodeAt (i_char ++)];
            b3 = table_char2index [text.charCodeAt (i_char ++)];

            data.writeByte ((b0 << 2) | ((b1 & 0x30) >> 4));
            data.writeByte (((b1 & 0x0f) << 4) | ((b2 & 0x3c) >> 2));
            data.writeByte (((b2 & 0x03) << 6) | b3);
         }

         data.position = 0;
         return data;
      }

      public static function EncodeByteArray2String(data:ByteArray):String
      {
         if (data == null)
         {
            return null;
         }

         var num_triples:int = data.length / 3;
         var num_extras:int = data.length - num_triples * 3;

         var num_chars:int = (num_extras > 0 ? num_triples + 1 : num_triples) * 4;
         var char_indexes:ByteArray = new ByteArray ();
         char_indexes.length = num_chars;

         var b0:int, b1:int, b2:int;

         data.position = 0;
         char_indexes.length = 0;

         for (var i_triple:int = 0; i_triple < num_triples; ++ i_triple)
         {
            b0 = data.readByte () & 0xFF; // "& 0xFF" is essential for negative values
            b1 = data.readByte () & 0xFF;
            b2 = data.readByte () & 0xFF;

            char_indexes.writeByte ((b0 & 0xFC) >> 2);
            char_indexes.writeByte (((b0 & 0x03) << 4) | (b1 >> 4));
            char_indexes.writeByte (((b1 & 0x0F) << 2) | (b2 >> 6));
            char_indexes.writeByte (b2 & 0x3F);
         }

         if (num_extras > 0)
         {
            b0 = data.readByte () & 0xFF; // "& 0xFF" is essential for negative values

            if (num_extras == 2)
            {
               b1 = data.readByte () & 0xFF; // "& 0xFF" is essential for negative values

               char_indexes.writeByte ((b0 & 0xFC) >> 2);
               char_indexes.writeByte (((b0 & 0x03) << 4) | (b1 >> 4));
               char_indexes.writeByte ((b1 & 0x0F) << 2);
               char_indexes.writeByte (64); // "="
            }
            else // num_extras == 1
            {
               char_indexes.writeByte ((b0 & 0xFC) >> 2);
               char_indexes.writeByte ((b0 & 0x03) << 4);
               char_indexes.writeByte (64); // "="
               char_indexes.writeByte (64); // "="
            }
         }

         var char_index:int;

         for (var i_char:int = 0; i_char < num_chars; ++ i_char)
         {
            char_index = char_indexes [i_char];
            char_indexes [i_char] = Base64Chars.charCodeAt(char_index);
         }

         char_indexes.position = 0;
         return char_indexes.readUTFBytes (num_chars);
      }
   }
}

This new sequel removed almost all timing factors in levels.
New elements in this sequel: spring, bomb, water and friction.

(Update: The release of Color Infection 2 will be delayed. I will try my best make it out before Christmas. In fact, the editor almost done, but I want to make the editor more powerful. )

It is released. Hope you enjoy it.

1. first remove the Jokers from the 54 cards,
2. then you will be given 4 solitaire cards randomly in the remaining 52 cards.
3. your goal is to get 24 by operating the 4 cards with addition, subtraction, multiplication, division. Each cards must be used once and only once.

For example, give you 4 cards: 1, 3, 9, 7, you can get 24 from (1 + 7) × (9 ÷ 3). There are exactly some cases without solutions, for example: 5, 5, 7, 9. But the success rate is very high. In all 1820 cases, there are only 474 cases without solutions (here fraction is not supported). This means about 74% of all cases are solvable.

One week ago, I decided to implement this game with flash. When it is almost done, an idea arised suddenly: how about change the rule to “give you 5 cards randomly, then your goal is to get the value of one card by operating the the other 4 cards with addition, subtraction, multiplication and division, each of the other 4 cards must be used once and only once“. Then I try it. Surprisingly, the success rate is even higher than the old one. In all 6188 cases, only 860 cases have no solutions, which means about 86% of all cases are solvable (solvable turns, see definitions below). Now I have decided to adopt the new rule for this game (named Math Solitaire).

Below, we name Case as Turn. A turn is represented as (a, b, c, d, e). For each turn there are 5 puzzles: (a, b, c, d)=>e, (a, b, c, e)=>d, (a, b, e, d)=>c, (a, e, c, e)=>b and (e, b, c, e)=>a.

Above statistics is get under 2 more minor rules:

• It is valid if the 5 numbers in a turn are a same value. In reality, with only one solitaire set, this is impossible.
• The intermediate results must not be a fraction, for example, (1/3 + 3) × 3 = 10 is not a valid solution for (3, 3, 3, 1) =>10.

Generally, if one of the 5 puzzles in a turn is solvable, then others are also solvable. But sometimes, it is not true. For example, (13, 13, 2, 10) => 2 has solutions, but (13, 13, 2, 2) => 10 has no solutions if 0 divide 0 is not valid or not defined. We call a turn as Solvable Turn once one puzzle in the turn is solvable. We call a turn as Good Solvable Turn if all the 5 puzzles in the turn are solvable. We call a solvable turn as Bad Solvable Turn if one puzzle in the turn is unsolvable. We call a turn as Simple Turn if the turn can be represented as (a, a, c, c, e), in other words, b=a, d=c. A simple turn at least has one solution (a – a) × e + c = c for puzzle (a, a, c, e)=>c.  So a simple turn is absolutely a solvable turn. A bad solvable turn must be a simple turn. But a simple turn is not always a bad solvable turn. If a simple turn is not a bad solvable turn, then it must be a good solvable turn.

As mentioned above, there are 6188 turns and 5328 solvable turns. Among these solvable turns, there are 392 bad solvable turns, 1183 simple turns, 4936 good solvable turns.

Only good solvable turns are packed In this game.

Some variations for this game:

• support extraction and power operations.
• support fraction as the intermediate results, for example, (1 / 3 + 3) × 3 = 10.
• the operands must be less than 10 (Jacks, Queens and Kings are also removed).
• set the result value as a specified number (4 randoms + 24 is one case of this variation).

The game will be released in this month.

Not only can this game be played online, but also can be played with friends in a party or in camping.

A: Yes.  I use the actionscript 3 port. Box2d physics engine is very cool!

Q: Do u use phun to do this?

A: No. I use my in-house editor. But the editor is much like phun. The editor is very not mature now. I will open source it later when it is a bit mature. BTW, I learned many from phunbox.

Q. Game’s well made enough, but way too slow.

A: Now the time scale element has been intrduced. You can press 0-9 to set time scale factor as the corresponding number. You can also press ~ or / in numpad to set the time scale factor as 0.5. Time scale with value of 0.5 means slow motion. Value 0 means pause the simulation. Value larger than 1 means fast lens

Q: Why only one level has green ball?

A: In later series, there will be more green ball levels. In the first version, I just make this design element claimed.

Q: Major flaw: the balls do not bounce. How do you have games that claim to be physics but the balls do not bounce? at all?

A: Most of them are steel balls. Only a few elastic balls in the game. And yes, sorry for the poor gfx representing. Now all balls looks the same. :(

Q: Its not loading for me.

A: Sorry. I really don’t know what is the cause. But it seems most people haven’t encountered this problem. Maybe you should update your flash player.

Q: Will you add a lvl creator?

A: Yes.

Very thanks, kong.

Play Color Infection

The difficulties (skill not puzzle) become harder and harder with levels going forward. The latter levels are almost impossible missions. You need luck to finish them.

The game is based on Box2d physics engine (as3 port).

Play pDecthlon

Because this is not a formal game. There are only 13 levels. Please enjoy it.

To play the game, use mouse to select the target box, then use AD keys or LEFT-RIGHT arrow keys to roll the target box. The target box can also be rolled by left-clicking (then either hold the mouse or not) an area without be occupied by boxes in the game field.

Now there are some level solutions on youtube. But please notice, the design of some levels have been modified since the solution videos were uploaded.

Play Teleporter Twins

Warning: Some levels are very hard. To finish the game, IQ must be higher than average level.